Գործարկեք որոշ vbs կոդ ֆայլի անվան փոփոխության ժամանակ

Գոյություն ունեն երկու պարզ WMI օրինակներ, որոնք հետևում են *.txt ֆայլերի փոփոխություններին C:\Test\ թղթապանակում:

Առաջինը նախատեսված է իրադարձությունների համաժամանակյա մշակման համար.

Option Explicit

Dim oWMIService, oEvents, s

Set oWMIService = GetObject("WinMgmts:\\.\root\CIMv2")
Set oEvents = oWMIService.ExecNotificationQuery( _
    "SELECT * FROM __InstanceOperationEvent " & _
    "WITHIN 1 WHERE " & _
    "TargetInstance ISA 'CIM_DataFile' AND " & _
    "TargetInstance.Drive = 'C:' AND " & _
    "TargetInstance.Extension = 'txt' AND " & _
    "TargetInstance.Path = '\\Test\\'")
Do
    With oEvents.NextEvent()
        s = "Event: " & .Path_.Class & vbCrLf
        With .TargetInstance
            s = s & "Name: " & .Name & vbCrLf
            s = s & "File Size: " & .FileSize & vbCrLf
            s = s & "Creation Date: " & .CreationDate & vbCrLf
            s = s & "Last Modified: " & .LastModified & vbCrLf
            s = s & "Last Accessed: " & .LastAccessed & vbCrLf
        End With
        If .Path_.Class = "__InstanceModificationEvent" Then
            With .PreviousInstance
                s = s & "Previous" & vbCrLf
                s = s & "File Size: " & .FileSize & vbCrLf
                s = s & "Last Modified: " & .LastModified & vbCrLf
            End With
        End If
    End With
    WScript.Echo s
Loop

Երկրորդը նախատեսված է իրադարձությունների ասինխրոն մշակման համար.

Option Explicit

Dim oWMIService, oSink

Set oWMIService = GetObject("WinMgmts:\\.\root\CIMv2")
Set oSink = WScript.CreateObject("WbemScripting.SWbemSink", "Sink_")
oWMIService.ExecNotificationQueryAsync oSink, _
    "SELECT * FROM __InstanceOperationEvent " & _
    "WITHIN 1 WHERE " & _
    "TargetInstance ISA 'CIM_DataFile' AND " & _
    "TargetInstance.Drive = 'C:' AND " & _
    "TargetInstance.Extension = 'txt' AND " & _
    "TargetInstance.Path = '\\Test\\'"
Do
    WScript.Sleep 1000
Loop

Sub Sink_OnObjectReady(oEvent, oContext)

    Dim s

    With oEvent
        s = "Event: " & .Path_.Class & vbCrLf
        With .TargetInstance
            s = s & "Name: " & .Name & vbCrLf
            s = s & "File Size: " & .FileSize & vbCrLf
            s = s & "Creation Date: " & .CreationDate & vbCrLf
            s = s & "Last Modified: " & .LastModified & vbCrLf
            s = s & "Last Accessed: " & .LastAccessed & vbCrLf
        End With
        If .Path_.Class = "__InstanceModificationEvent" Then
            With .PreviousInstance
                s = s & "Previous" & vbCrLf
                s = s & "File Size: " & .FileSize & vbCrLf
                s = s & "Last Modified: " & .LastModified & vbCrLf
            End With
        End If
    End With
    WScript.Echo s

End Sub

CIM_DataFile օրինակի հատկությունների մասին լրացուցիչ տեղեկություններ կարող եք գտնել հղումը MSDN-ում: